Commodore 64 Computed Restore in BASIC

COMPREST
Copy, paste, and tokenize the code from the text area below to COMPREST

10 DATA "ROOM 10",20,0,40,0

20 DATA "ROOM 20",0,10,30,0

30 DATA "ROOM 30",0,40,0,20

40 DATA "ROOM 40",30,0,0,10

45 GOTO 310

50 REM GET-A-ROOM SUBROUTINE

60 REM EXPECTS ROOM # IN VAR RO

70 BE=FNDEEK(43):EN=FNDEEK(45)

80 IF FNDEEK(BE+2)=RO THEN 110

90 BE=FNDEEK(BE):IF BE<EN THEN 80

100 PRINT "ERROR, LINE ";RO;" NOT FOUND":END

110 REM PERFORM COMPUTED RESTORE

120 POKE 65,((BE+4)AND255)

130 POKE 66,INT((BE+4)/256)

140 READ DE$,N,S,E,W

150 PRINT "YOU ARE IN ";DE$

160 PRINT "EXITS ARE:"

170 IF N<>0 THEN PRINT "  NORTH"

180 IF S<>0 THEN PRINT "  SOUTH"

190 IF E<>0 THEN PRINT "  EAST"

200 IF W<>0 THEN PRINT "  WEST"

210 RETURN

300 REM BELOW IS A DOUBLE-BYTE PEEK

310 DEF FN DEEK(X)=PEEK(X)+256*PEEK(X+1)

320 RO=10:GOSUB 50

330 PRINT "COMMAND:";

340 INPUT D$

350 LR=RO

360 IF D$="N" THEN IF N<>0 THEN RO=N

370 IF D$="S" THEN IF S<>0 THEN RO=S

380 IF D$="E" THEN IF E<>0 THEN RO=E

390 IF D$="W" THEN IF W<>0 THEN RO=W

400 IF LR<>RO THEN GOSUB 50:GOTO 330

410 PRINT "YOU CANNOT GO THAT DIRECTION"

420 GOTO 330

The above program was intended to demonstrate a simple technique for leaving array-oriented data records in DATA statements. Records are sought by using a computed RESTORE.

The computed RESTORE itself is performed entirely in BASIC.

The subroutine at line 50 searches from the beginning of BASIC's program storage to it's end via traversing the linked-list of program lines. As it traverses, it will stop if the line-number matches the variable RO.

The DATA statements are left at the top of the program so that they can be found quickly using this sequential searching technique.

A user-defined function DEEK is created in line 310 to perform a double-byte peek for the search routine.

Line 110 implements a computed-RESTORE in BASIC. The address of the BASIC statement with the found data-line number is incremented by 4 ( to skip past the 16-bit link and the 16-bit line-number ) and is then POKE'd into locations 65 and 66 so that READ will pick up this line.

Back to Jimbo's Demented Software

Back to Jimbo's Home Page